解决Win10指定内网IP提示“出现一个意外，不能完成所有你设置中要求的更改”

今天去修改Win10内网IP时弹出了下图的错误，百度了一下，解决的办法就是使用命令方式去修改内网IP，突然觉得命令方式修改比手功方便，然后就将它制作成批处理了，保存为以 内网IP修改.bat ，并以管理员身份运行，即可食用

@echo off
setlocal EnableDelayedExpansion
CHCP 65001
mode con: cols=70 lines=35
:ch
set rr="HKCU\Console\%%SystemRoot%%_system32_cmd.exe"
reg delete %rr% /f>nul
reg add %rr% /v "WindowPosition" /t REG_DWORD /d 0x01040224 /f>nul
set Nic="以太网"
set Addr=192.168.88.1
set Mask=255.255.255.0
set Gway=192.168.88.253
set Dns1=8.8.8.8
set Dns2=8.8.4.4
cls
echo.#------------------------  lovebiu.com 制作  ------------------------#
echo. 1.指定内网IP及DNS
echo.
echo. 2.自动获取IP及DNS
echo.                              
echo.#--------------------------------------------------------------------#
echo. (注：必须以管理员身份运行)
echo. 
set/p aa=输入序号后回车确定:
echo.%aa%|findstr "^[1-2]$">nul&&goto M%aa%
goto ch
 
:M1
echo ------------------------------------------------------
echo. 正在配置%Nic%网络接口
echo. IP地址 = %Addr% 
echo. 子网掩码 = %Mask%
echo. 网关 =%Gway% 
echo. 首选DNS = %Dns1%
echo. 备用DNS = %Dns2%
echo. 请稍等……
echo ------------------------------------------------------
netsh interface ip set address name=%Nic% source=static addr=%Addr% mask=%Mask% gateway=%Gway%
netsh interface ip set dns name=%Nic% source=static addr=%Dns1% register=PRIMARY
netsh interface ip add dns name=%Nic% addr=%Dns2% index=2
echo. 配置完毕，回车返回……
pause
goto ch
 
:M2
echo ------------------------------------------------------
echo. 正在配置%Nic%网络接口，为自动获取IP地址及DNS地址
echo ------------------------------------------------------
netsh interface ip set address name=%Nic% source=dhcp 
netsh interface ip set dns name=%Nic% source=dhcp
echo. 配置完毕，回车返回……
pause
goto ch